【Visual Basic】vb6的ListView控件，对Access2003数据库的增删改查，判断是否有中文、多窗体操作

vb6对Access2003数据库的增删改查并不复杂，可以通过ado对象轻松完成，下面举个小例子，同时说明vb6中的ListView控件的使用。虽然在《【Visual Basic】列表控件ListView的增删改查、模态对话框、禁止窗口调整大小》曾经对VB.NET的ListView控件进行详细的说明，但是证明微软就是个坑爹货，vb6对于ListView实现的代码居然跟VB.NET有着彻底的不同，似乎换了一门语言似得的。改代码什么的最讨厌的。

首先，在vb6生成的工程文件夹中有着一个db1.mdb这个Access2003的文件，

db1.mdb的密码为admin，里面就一张userinfo，具体如下，就一张简单到不能再简单的用户信息表，里面有三个字段，此处的id没有半点意义，纯粹因为Access2003在任何一张表都要求主键而设置的，关键是用户名与密码这两个字段。

具体怎么创建的，设置Access2003密码的，我在《【Access2003】表的新建、用sql语句查询；关闭警告信息；修改数据库密码；修复数据库》（点击打开链接）中已经说过了，这里不再赘述。

下面建立如下的一个vb工程，利用db1.mdb来存储用户信息，每次一打开这个exe，自动加载Access2003的用户信息。提供添加数据、修改数据、删除数据的功能。在增删改查的过程中，db1.mdb中的内容同时被修改。无论这个exe退出与否，信息自动存储。

不得向数据库中插入中文数据。

删除信息的时候，自动更新编号，保持1,2,3,4,....的升序关系，不会像Access2003中自增的Id断层。

制作过程如下

1、首先，新建一个vb工程，如下图，通过工程->部件，打开部件管理器，vb6提供的基本控件不够用。根本就没有连接数据库，与ListView这个组件。

某些精简版的vb6可能会出现问题，建议用完整版的vb6

选中Microsoft ADO Data Control 6.0 OLEDB，为这个工程添加数据库功能。

添加Microsoft Windows Common Controls，我们需要其中的ListView控件。

2、之后，对Form1进行如下的布局，拖入一个ListView1，三个Button，将Form1的标题的Caption改改，同时把Border Style改成1-Fixed Style，这可比VB.NET简单得多。同时把MaxButton与MinButton都改成Flase，禁用最大最小化按钮。

3、随后，如下图新建一个Form2窗体

4、将Form2布局调整到如下的布局，同样是禁用最大最小化按钮，拖入两个标签文本，其Alignment属性为2-Center，两个编辑框，一个按钮。在调整窗体的过程中，可以选中多个控件，利用”格式“->对齐、统一尺寸等按钮调节到一个美观的程度。

5、在Form1窗体的编辑状态激活的情况下，按F7打开代码界面，写入如下代码，这里的思想与《【Visual Basic】列表控件ListView的增删改查、模态对话框、禁止窗口调整大小》同样，只是由于vb6与vb.net对ListView控件的操作不同，导致代码有稍许修改，同时加入了vb6对Access2003数据库的增删改查的内容，其实就是vbscript也就是asp对access数据库操作的内容，这个在《【ASP】ASP对Access数据库的连接、增删改查及ASP的基本语法》（点击打开链接）中已经讨论过了。唯一值得注意的是，所有vb操作数据库的语句中的表、列（字段）必须用[]，中括号标明，如果不标明则会报错。具体看注释：

'初始化ListView控件的过程，一会儿在Form_Load窗体加载的过程会被调用
Sub ListView_Init()
    ListView1.View = lvwReport '设置列表显示方式
    ListView1.GridLines = True '显示网络线
    ListView1.LabelEdit = lvwManual '禁止标签编辑
    ListView1.FullRowSelect = True '选择整行
     '初始化三个列头，这里的宽度注意不要占满100%，会出现不美观的横向滚动条
    ListView1.ColumnHeaders.Add , , "编号", ListView1.Width / 4
    ListView1.ColumnHeaders.Add , , "用户名", ListView1.Width / 3
    ListView1.ColumnHeaders.Add , , "密码", ListView1.Width / 3
End Sub

'添加按钮
Private Sub Command1_Click()
    Form2.selectItemIndex = -1
    Form2.Show vbModal 'Form2窗体以模态框的方式打开
End Sub

'修改按钮
Private Sub Command2_Click()
    If ListView1.ListItems.Count <> 0 Then '如果用户有选中东西
        Form2.selectItemIndex = ListView1.SelectedItem.Index '将用户选中的内容传递到Form2
        Form2.Text1.Text = ListView1.ListItems(ListView1.SelectedItem.Index).SubItems(1)
        Form2.Text2.Text = ListView1.ListItems(ListView1.SelectedItem.Index).SubItems(2)
        Form2.Show vbModal
    Else
        MsgBox "请选中其中的一项！", vbOKOnly, "警告"
    End If
End Sub

'删除按钮
Private Sub Command3_Click()
    If ListView1.ListItems.Count <> 0 Then '如果用户有选中东西
        '连接数据库
        Dim conn As New ADODB.Connection
        Dim rs As New ADODB.Recordset
        'Data Source后面是数据库的路径和文件名
        'Database password后面的是这个数据库的密码
        conn.Open "Provider=Microsoft.Jet.OleDb.4.0;Data Source=" & App.Path & "/db1.mdb;Jet OleDb:Database password=admin"
        '删除数据库中的一项
        Username_Deleted = ListView1.ListItems(ListView1.SelectedItem.Index).SubItems(1)
        conn.Execute "delete from [userinfo] where [username]='" & Username_Deleted & "';"
        '删除ListView1中的一项
        ListView1.ListItems.Remove ListView1.SelectedItem.Index
        '更新ListView1中的编号
        For i = 1 To Form1.ListView1.ListItems.Count
            ListView1.ListItems(i).Text = i '此处不能用SubItems(0)来取第一列
        Next
        conn.Close
    Else
        MsgBox "请选中其中的一项！", vbOKOnly, "警告"
    End If
End Sub

'窗体加载函数
Private Sub Form_Load()
    '初始化窗体
    Call ListView_Init
    '连接数据库
    Dim conn As New ADODB.Connection
    Dim rs As New ADODB.Recordset
    'Data Source后面是数据库的路径和文件名
    'Database password后面的是这个数据库的密码
    conn.Open "Provider=Microsoft.Jet.OleDb.4.0;Data Source=" & App.Path & "/db1.mdb;Jet OleDb:Database password=admin"
    '最后一个参数，1打开的是只读的，读写则为为3。
    '写下数据库的查询语句select，实现你想要的功能
    rs.Open "Select * From userinfo", conn, 1, 3
    '将查询到的东西，一一加载到ListView1中
    If (rs.BOF And rs.EOF) Then
        MsgBox ("数据库没有数据！")
    Else
        i = 0
        Do While Not rs.EOF
        i = i + 1
            ListView1.ListItems.Add , , i
            ListView1.ListItems(i).SubItems(1) = rs.Fields("username")
            ListView1.ListItems(i).SubItems(2) = rs.Fields("password")
        rs.MoveNext
        Loop
    End If
    rs.Close
    conn.Close
End Sub

6、之后是Form2的代码，根据Form1传递过来的指定，实现相应的功能，功能的判断根据全局变量Public selectItemIndex As Integer所控制，具体请看注释：

Public selectItemIndex As Integer '供Form1所控制的全局变量，用于判断是修改，还是添加项

'判断是否为中文的过程，在vb中有返回值的过程写成Function，没有返回值的过程写成Sub
Function isChineseExist(s As String) As Boolean
    Dim i As Integer
    For i = 1 To Len(s)
        If Asc(Mid(s, i, 1)) < 0 Then
            isChineseExist = True
            Exit Function
        End If
    Next
    isChineseExist = False
End Function

'窗体的加载过程
Private Sub Form_Load()
    If selectItemIndex = -1 Then
        Me.Caption = "添加数据"
        Command1.Caption = "添加数据"
    Else
        Me.Caption = "修改数据"
        Command1.Caption = "修改"
    End If
End Sub

'按钮的点击过程
Private Sub Command1_Click()
    '连接数据库
    Dim conn As New ADODB.Connection
    Dim rs As New ADODB.Recordset
    'App.Path代表exe所在的路径
    conn.Open "Provider=Microsoft.Jet.OleDb.4.0;Data Source=" & App.Path & "/db1.mdb;Jet OleDb:Database password=admin"
    If selectItemIndex = -1 Then '如果是添加
        If isChineseExist(Text1.Text) Or isChineseExist(Text2.Text) Then
            MsgBox "用户名、密码，任意一项不能含有中文！", vbOKOnly, "警告"
        Else
            If Text1.Text = "" Or Text2.Text = "" Then
                MsgBox "用户名、密码，任意一项不能为空！", vbOKOnly, "警告"
            Else
                '窗体项的添加
                Form1.ListView1.ListItems.Add , , Form1.ListView1.ListItems(Form1.ListView1.ListItems.Count) + 1
                Form1.ListView1.ListItems(Form1.ListView1.ListItems.Count).SubItems(1) = Text1.Text
                Form1.ListView1.ListItems(Form1.ListView1.ListItems.Count).SubItems(2) = Text2.Text
                '数据库的添加
                conn.Execute "insert into [userinfo]([username],[password]) values('" & Text1.Text & "','" & Text2.Text & "');"
                '清空两个编辑框的内容
                Text1.Text = ""
                Text2.Text = ""
                '关闭Form2这个窗体，vb6没有Me.Close只有Me.Hide
                Me.Hide
            End If
        End If
    Else '如果是修改其中的一项
        If isChineseExist(Text1.Text) Or isChineseExist(Text2.Text) Then
            MsgBox "用户名、密码，任意一项不能含有中文！", vbOKOnly, "警告"
        Else
            If Text1.Text = "" Or Text2.Text = "" Then
                MsgBox "用户名、密码，任意一项不能为空！", vbOKOnly, "警告"
            Else
                '先存放这一项的用户名与密码，之后用update语句逐一修改，注意：update语句只能一次修改一个字段
                OldUserName = Form1.ListView1.ListItems(selectItemIndex).SubItems(1)
                OldPassWord = Form1.ListView1.ListItems(selectItemIndex).SubItems(2)
                '修改窗体的内容
                Form1.ListView1.ListItems(selectItemIndex).SubItems(1) = Text1.Text
                Form1.ListView1.ListItems(selectItemIndex).SubItems(2) = Text2.Text
                '修改数据库
                conn.Execute "update [userinfo] set [username]='" & Text1.Text & "' where [username]='" & OldUserName & "';"
                conn.Execute "update [userinfo] set [password]='" & Text1.Text & "' where [password]='" & OldPassWord & "';"
                '清空两个编辑框的内容
                Text1.Text = ""
                Text2.Text = ""
                '关闭此对话框
                Me.Hide
            End If
        End If
    End If
    '关闭数据库的连接
    conn.Close
End Sub

版权声明：本文为博主原创文章，未经博主允许不得转载。

时间： 2024-12-08 18:37:03

【Visual Basic】vb6的ListView控件，对Access2003数据库的增删改查，判断是否有中文、多窗体操作的相关文章

C#在listview控件中显示数据库数据

一.了解listview控件的属性 view:设置为details columns:设置列 items:设置行 1.将listview的view设置为details 2.设置列属性 点击添加,添加一列 设置一列的Text属性,这就是列名 添加三列 3.编辑items属性,添加一行数据 编辑Text属性,添加一行的第一个数据 编辑subitems属性,添加一行中的其他数据 添加两个数据 填写结果 二.在listview中显示数据库数据 //在listview中显示数据库数据 private voi

Android数据库的增删改查和ListView以及页面跳转的实现

不多说什么,直接看代码:先创建一个person实体对象. import java.io.Serializable; public class Person implements Serializable{ private static final long serialVersionUID=1L; private Integer id; private String name; private String phone; private Integer amount; public Intege

listview控件及其与数据库的连接

一.显示数据 1.视图 -----小三角--视图-Details,该选项最常用,选中之后会以表格样式呈现. 2.设置列头 ----右键--编辑列 --添加 先编辑列,再编辑项 编辑列右边的属性:Text是列名,DisplayIndex是显示列的顺序 3.添加行数据 ----右键--编辑项--添加 编辑项右边的属性:Text设置第一列的数据,SubItems集合设置其余列的数据////上边是手动添加随意数据 如果是用数据库的数据的话可以在数据库的数据之前额外添加一列序号放在li.Text里,方便查

ListView窗体的增删改查

ListView 控件可使用四种不同视图显示项目. 通过此控件,可将项目组成带有或不带有列标头的列,并显示伴随的图标和文本. 可使用 ListView 控件将称作 ListItem 对象的列表条目组织成下列四种不同的视图之一:1.大(标准)图标2.小图标3.列表4.报表 View 属性决定在列表中控件使用何种视图显示项目. 还可用 LabelWrap 属性控制列表中与项目关联的标签是否可换行显示.另外,还可管理列表中项目的排序方法和选定项目的外观. 一.建立一个AppCode来存放新建的类 二.

Android SQLite的使用，基本的增删改查效果，以及ListView的效果显示

1 package com.example.sqlitetest; 2 3 import java.util.ArrayList; 4 import java.util.List; 5 import android.content.ContentValues; 6 import android.content.Context; 7 import android.database.Cursor; 8 import android.database.sqlite.SQLiteDatabase; 9

【Visual Basic】列表控件ListView的增删改查、模态对话框、禁止窗口调整大小

列表控件ListView是窗体中核心组件之一,在各种窗体程序得到广泛应用.在<[mfc]学生信息管理,实现List控件节点的增删改查>(点击打开链接)中极其难以实现列表控件ListView的增删改查,在vb中可以轻松实现,下面举一个列子来说明这个问题. 如上图的一个ListView控件,点击"添加"按钮,在弹出的模态窗口,可以为ListView控件添加相应的项. 通过"删除"按钮可以删除选中的项.通过"修改"按钮,选中的项的值将会传递

ListView控件的Insert、Edit和Delete功能（第二部分）

本系列文章将通过一个简单的实例,结合我自己使用ListView的情况,展示如何用ASP.NET 3.5 ListView控件进行基本的Insert.Edit和Delete操作. 系统要求: Windows XP SP2 or higher VS2008 Beta 2 or Visual Web Developer 2008 Express Edition Beta 2 在本系列的第一篇中,介绍了如何实现ListView的Insert功能.本篇介绍如何实现Edit功能. 实现Edit功能 在Lis

ListView控件的Insert、Edit和Delete功能（第一部分）

摘自:http://blog.ashchan.com/archive/2007/08/28/listview-control-insert-edit-amp-delete-part-1aspx/ ListView是ASP.NET 3.5新提供的一个控件,它支持GridView类似的功能,并将HTML渲染的责任交由使用者来把控,而这正是GridView的一大劣势(它生成的乱七八糟的HTML输出,即使通过CSS Friendly Control Adapters来净化,也还是让人头痛得不行).使用L

C#如何解决对ListView控件更新以及更新时界面闪烁问题

第一个问题:如何更新ListView控件内容 很多时候运行窗体程序时,由于程序中使用了多线程加之操作不当,所以在对控件操作时会出现下面这样的异常: 这是因为我们在窗体中添加的控件都有属于自己的线程,所以不能从其它线程来访问它. 那要如何解决? 使用委托:MethodInvoker,我用这个挺方便的.下面举一个用例: 1 //调用InitListView(),便可以对ListView控件进行自由更新啦 2 private void InitListView() 3 { 4 MethodInvoke