积雪材质

概述

积雪材质是我自己给这个材质取的名字，既然是积雪，那顾名思义，雪是从天而降的，因此积雪都是在物体朝上的表面；不管你的模型怎么摆放 ，雪都保证是积在物体朝上（在unity里就是y轴正方向）的表面，如下图所示：

实现原理

要保证向上的面有积雪，其实就是模型表面的法线方向与世界坐标空间的Y轴正方向保持一致积雪多，否则积雪就少雪，所以将模型的法线方向normal从模型空间转化到世界空间，然后与y轴正方向float3（0，1，0）做点积，根据结果来确认法相的朝向和Y轴的夹角大小，从而确认是否积雪；这个和之前的边缘光材质是一样的道理，不同的是，那个是考虑模型法线与视线方向的夹角；

Shader代码实现

终于到代码实现了，想想有点小激动，嘿嘿。鉴于vf写灯光比较复杂，本例的材质是没有实现灯光支持的，废话不多说，先从属性定义开始，至少需要两张贴图，然后定义一个参数控制雪的数量：

Properties {
	_MainTex ("Base (RGB)", 2D) = "white" {}
	_SnowTex ("SnowTexture(RGB)",2D) = "white"{}
	_SnowCount ("SnowCount", Range (0.0, 1)) = 0.078
}

定义输入结构体和输出结构体；

			struct appdata_t {
				float4 vertex : POSITION;
				float2 texcoord : TEXCOORD0;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 vertex : SV_POSITION;
				half2 texcoord : TEXCOORD0;
				half2 snowUV : TEXCOORD1  ;
				fixed4 snow : COLOR;//定义一个四元数用来传递将积雪位置到frag函数
				UNITY_FOG_COORDS(1)
			};

接下来是比较关键的vert函数部分，在这里获得模型的法线，并将法线方向转换到世界空间与Y方向轴做点积，确定积雪的面，关键代码如下：

float3 worldNormal = mul((float3x3)_Object2World ,v.normal );//将法线转换到世界空间
float rim = 1-saturate(dot(float3(0,1,0),worldNormal ));//将世界空间的法线方向与Y轴做点积运算
o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
o.snowUV = TRANSFORM_TEX(v.texcoord , _SnowTex);
o.snow = pow(rim,_SnowCount*64);//控制积雪的量，这个值将传入到frag函数里面用来混合两张贴图

Frag函数比较简单，用vert传入的值i.snow将两张贴图混合，做出积雪的效果。下面是完整代码

VF版本代码01

Shader "PengLu/Unlit/SnowVF" {
Properties {
	_MainTex ("Base (RGB)", 2D) = "white" {}
	_SnowTex ("SnowTexture(RGB)",2D) = "white"{}
	_SnowCount ("SnowCount", Range (0.0, 1)) = 0.078
}

SubShader {
	Tags { "RenderType"="Opaque" }
	LOD 100

	Pass {
		CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fog

			#include "UnityCG.cginc"

			struct appdata_t {
				float4 vertex : POSITION;
				float2 texcoord : TEXCOORD0;
				float3 normal : NORMAL;
			};

			struct v2f {
				float4 vertex : SV_POSITION;
				half2 texcoord : TEXCOORD0;
				half2 snowUV : TEXCOORD1  ;
				fixed4 snow : COLOR;
				UNITY_FOG_COORDS(1)
			};

			sampler2D _MainTex;
			sampler2D _SnowTex;
			float4 _MainTex_ST,_SnowTex_ST;
			float _SnowCount;
			v2f vert (appdata_t v)
			{
				v2f o;
				o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
				float3 worldNormal = mul((float3x3)_Object2World ,v.normal );
				float rim = 1-saturate(dot(float3(0,1,0),worldNormal ));
				o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.snowUV = TRANSFORM_TEX(v.texcoord , _SnowTex);
				o.snow = pow(rim,_SnowCount*64);
								UNITY_TRANSFER_FOG(o,o.vertex);
				return o;
			}

			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.texcoord);
				fixed4 snow = tex2D(_SnowTex,i.snowUV);
				col = lerp(snow,col,saturate(i.snow));
				UNITY_APPLY_FOG(i.fogCoord, col);
				UNITY_OPAQUE_ALPHA(col.a);

				return col;
			}
		ENDCG
	}
}

}

带法线贴图效果的实现

上面的代码由于是直接由顶点的法线计算，所以可以看到积雪的效果还是有点粗糙，因此可以考虑用法线贴图来事的积雪的效果更加精确和细腻一些。同样这个shader并没有实现光照的效果，还是一个Unlit材质；原理差不多，因此不做过多的解析，完整代码即效果如下：

VF版本代码02：

Shader "PengLu/Unlit/SnowBumpVF" {
	Properties {
	_MainTex ("Base (RGB)", 2D) = "white" {}
	_BumpMap ("BaseBump", 2D) = "bump" {}
	_SnowTex ("SnowTexture(RGB)",2D) = "white"{}
	_SnowCount ("SnowCount", Range (0.01, 1)) = 0.078
}

SubShader {
	Tags { "RenderType"="Opaque" }
	LOD 200

	Pass {
		CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fog

			#include "UnityCG.cginc"

			struct v2f {
				float4 vertex : SV_POSITION;
				half2 texcoord : TEXCOORD0;
				half2 snowUV : TEXCOORD1  ;
				// fixed4 snow : COLOR;
				float3 tangent:TEXCOORD2;
				float3 binormal : TEXCOORD3;
				float3 normal : TEXCOORD4;
				UNITY_FOG_COORDS(1)
			};

			sampler2D _MainTex,_BumpMap;
			sampler2D _SnowTex;
			float4 _MainTex_ST,_SnowTex_ST;
			float _SnowCount;
			v2f vert (appdata_full v)
			{
				v2f o;
				o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
				o.tangent = v.tangent.xyz;
				o.normal = v.normal;
				o.binormal=cross(v.normal,v.tangent.xyz)*v.tangent.w;

				o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.snowUV = TRANSFORM_TEX(v.texcoord , _SnowTex);
								UNITY_TRANSFER_FOG(o,o.vertex);
				return o;
			}

			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.texcoord);
				fixed4 snow = tex2D(_SnowTex,i.snowUV);
				float3x3 rotation=float3x3 (i.tangent.xyz,i.binormal,i.normal);
				float3 N = UnpackNormal(tex2D(_BumpMap,i.texcoord));
				N=normalize(mul(N,rotation));
				N = mul((float3x3)_Object2World ,N );
				float rim = 1-saturate(dot(float3(0,1,0),N));
				float4 lerpsnow = pow(rim,_SnowCount*16);
				col = lerp(snow,col,saturate(lerpsnow));
				UNITY_APPLY_FOG(i.fogCoord, col);
				UNITY_OPAQUE_ALPHA(col.a);

				return col;
			}
		ENDCG
	}
}

}

VF版本代码02效果：

版权声明：本文为博主原创文章，未经博主允许不得转载。