XE3随笔6:SuperObject 的 JSON 对象中还可以包含 "方法"

SuperObject 的 JSON 对象中还可以包含 "方法", 这太有意思了; 其方法的格式是:

procedure Method(const This, Params: ISuperObject; var Result: ISuperObject);

//另外, 这是其数据类型的枚举:
TSuperType = (stNull, stBoolean, stDouble, stInt, stObject, stArray, stString, stMethod);

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Keyboard;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses SuperObject;

//方法1; 参数列表是规定好的, 但这里没使用参数
procedure Method1(const This, Params: ISuperObject; var Result: ISuperObject);
begin
  ShowMessage(‘Hello‘);
end;

//方法2; 这里使用了第二个参数; 这里的第二个就是调用时的第一个
procedure Method2(const This, Params: ISuperObject; var Result: ISuperObject);
begin
  ShowMessage(Params.AsJSon);
end;

//方法3; 这里使用了第一个参数; 第一个参数值使用时无需传递, 它代表使用方法的对象本身
procedure Method3(const This, Params: ISuperObject; var Result: ISuperObject);
begin
  ShowMessage(This.AsJSon);
end;

//方法4; 这里使用了第三个参数; 这是调用时的返回值, 如果不给它赋值, 调用时将无返回值
procedure Method4(const This, Params: ISuperObject; var Result: ISuperObject);
begin
  Result := This;
  Result.Merge(Params, True); {合并}
end;

//第一种使用方法
procedure TForm1.Button1Click(Sender: TObject);
var
  jo: ISuperObject;
begin
  jo := SO(‘{"X":"Y"}‘);
  jo.M[‘jm1‘] := @Method1;
  jo.M[‘jm2‘] := @Method2;
  jo.M[‘jm3‘] := @Method3;
  jo.M[‘jm4‘] := @Method4;

  jo.call(‘jm1‘);                      // Hello

  jo.call(‘jm2‘, SO(‘{"A":"B"}‘));     // {"A":"B"}
  jo.call(‘jm2‘, ‘{"A":"B"}‘);         // {"A":"B"}

  jo.call(‘jm3‘);                      // {"X":"Y"}

  jo.call(‘jm4‘, ‘{"B":null}‘);
  ShowMessage(jo.AsJSon);              // {"X":"Y","B":null}
end;

//第二种使用方法
procedure TForm1.Button2Click(Sender: TObject);
var
  t,jo: ISuperObject;
begin
  jo := SO(‘{"X":"Y"}‘);
  jo.M[‘jm1‘] := @Method1;
  jo.M[‘jm2‘] := @Method2;
  jo.M[‘jm3‘] := @Method3;
  jo.M[‘jm4‘] := @Method4;

  jo[‘jm1()‘];                           // Hello

  jo[‘jm2(‘ + ‘{"A":"B"}‘ + ‘)‘];        // {"A":"B"}
  jo[‘jm2({A:B})‘];                      // {"A":"B"}

  jo[‘jm3()‘];                           // {"X":"Y"}

  jo[‘jm4(‘ + ‘{"B":null}‘ + ‘)‘];
  ShowMessage(jo.AsJSon);                // {"X":"Y","B":null}
end;

end.