Unity-Shader-镜面高光Phong&BlinnPhong-油腻的师姐在哪里

【旧博客转移 - 2016年4月4日 13:13 】

油腻的师姐：

以前玩过一款很火热的端游《剑灵》，剑灵刚出来的时候，某网页游戏广告视频中有句台词：“我不断的在寻找，有你的世界在哪里”，该广告中的人物，音效都模仿了剑灵，而《剑灵》中的人物模型表面看上去油光发亮，所以就被网友改成了：“我不断的洗澡，油腻的师姐在哪里”

像这样（皮肤表面的高光）

这样

还有~ 这样

其实这是使用了镜面反射着色，除了剑灵，其他很多高品质的AAA级游戏也都使用了不同的镜面高光，来增强视觉冲击力和超现实感。

Phong高光类型

Phong光照模型是图形学中表现很友好的高光类型，是一种非常常见的镜面高光模型，从游戏到电影都有诸多应用

镜面反射跟漫反射的区别就是，漫反射的反射光是很分散的。镜面反射的反射光会集中在一起，

视线离反射光越近，射入我们眼中的光也就越多，反之则看不到反射光

Phong光照计算公式

Spec = pow( max(0 ,cos<R, V>), gloss)

R：反射光向量

V：视线向量

gloss：镜面的光滑程度，gloss越大就表示越光滑

Phong光照模型的Shader实现

Shader "lijia/Phong"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Specular("Specular", Range(1, 20)) = 1
        _SpecColor("SpecColor", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float3 normal : TEXCOORD1;
                float3 lightDir : TEXCOORD2;
                float4 objPos : TEXCOORD3;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            float4 _LightColor0;

            float _Specular;
            float4 _SpecColor;

            v2f vert (appdata_full v)
            {
                v2f o;
                o.objPos = v.vertex;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.normal = v.normal;
                o.lightDir = ObjSpaceLightDir(v.vertex);//把光向量从世界空间转成模型空间
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float3 L = normalize(i.lightDir);
                float3 N = normalize(i.normal);
                float3 viewDir = normalize(ObjSpaceViewDir(i.objPos));//计算出视线

                float diff = saturate(dot(L, N));
                float3 reflection = normalize(2.0 * N * diff - L);//反射向量
                float spec = pow(max(0, dot(reflection, viewDir)), _Specular);
                float3 finalSpec = _SpecColor.rgb * spec;
                //漫反射+镜面高光+环境光
                float3 finalLight = diff * _LightColor0 + finalSpec + UNITY_LIGHTMODEL_AMBIENT;

                fixed4 col = tex2D(_MainTex, i.uv);
                return col * float4(finalLight, 1);
            }
            ENDCG
        }
    }
}

计算反射向量

Phong用到的是反射向量，计算反射向量的公式是

R = 2*N(dot(N, L)) - L

这个公式是根据向量的投影公式以及平行四边形法则推导出来的

详细步骤请看这篇文章，讲的非常好

http://www.cnblogs.com/graphics/archive/2013/02/21/2920627.html

Blinn-phong光照模型

blinn是一个人的名字，他叫吉姆·布林，图形学界的大牛，他发现了使用半角向量代替反射向量的计算方式

原理是通过视线向量跟光向量的半角向量代替反射向量

halfVector = normalize( L + V );

这样提高了代码的计算效率，在视觉上也更加平滑，因此它成为了很多CG软件中默认的光照模型

Shadre代码跟Phong类似，我就不贴了

将Phone光照用到剑灵模型上的效果

右边是Game视图中加了后期效果的

参考资料：

《ShaderLab开发实战详解》

《Unity着色器和屏幕特效开发秘籍》

【浅墨Unity3D Shader编程】之十三 单色透明Shader & 标准镜面高光Shader