利用DoHome APP和音箱控制LED灯实验参考步骤 / 憋错料

准备材料：

Arduino Uno 一块

Arduino 扩展板购买链接

DT-06模块一个购买链接

安卓手机一个

小度音箱一个

小灯珠一个

杜邦线若干

1.DT-06固件的烧录

1.1打开ESP模块下载工具ESPFlashDownloadTool,选择需要下载的固件，填写下载地址，推荐使用 ESP8266 Download TOOL,配置信息如下：

1.2 选择实际的串口，选择下载速度

1.3点击ERASE，先插除，再点击START,开始下载

工具下载及详细请看：http://bbs.doit.am/forum.php?mod=viewthread&tid=208

DT-06固件.bin文件下载链接

2.硬件电路的连接

小灯珠的R———arduino扩展板D2口

小灯珠的G———arduino扩展板D3口

小灯珠的B———arduino扩展板D4口

小灯珠的GND———arduino扩展板GND

DT-06安装到arduino扩展板的串口排插位置

3.DT-06通讯协议

通信方式：串口通讯

波特率：115200，无奇偶校验，8位数据位，1位停止位

每条命令以\r\n结尾。

3.1、控制命令

3.1.1 DT06->arduino

cmd=ctrl&message=power_off|r|g|b|w|m

power_off表示开关灯操作，0表示关，1表示开

r，g，b，w，m几个字段分别表示红、绿、蓝、白、暖光的颜色值,颜色值取值范围是0~5000

3.1.2 Arduino->DT06

cmd=ctrl&ok;

3.2、上传状态

3.2.1 Arduino->DT06

上传基本状态

cmd= stat&status= soft_power

cmd=stat代表基本状态 50s传一次

上传扩展状态

cmd=ext_stat&status=r|g|b|w|m

cmd=ext_stat 代表扩展状态 60s传一次

3.2.2 DT06->arduino

基本状态：cmd=stat& ok

扩展状态：cmd=ext_stat&ok

4.Arduino UNO 程序的编写

//材料：UNO+DT06
#include <EEPROM.h>

/****************************IO引脚定义*****************************/

#define MAX_PACKETSIZE  512

#define DataSerial         Serial

#define PWM_R     2
#define PWM_G     3
#define PWM_B     4
#define PWM_W     5
#define PWM_M     6

//#define DebugSerial     Serial1
struct config_type
{
    uint8_t ledswitch;
    uint16_t r;
    uint16_t g;
    uint16_t b;
    uint16_t w;
    uint16_t m;
};

config_type config;

//uartdata
char buffUart[MAX_PACKETSIZE];
unsigned int buffUartIndex = 0;
unsigned long preUartTick = 0;
int eeAddress = 0;

char strStat[64] = {0};
char strExtStat[128] = {0};

/*
   保存参数到EEPROM
*/
void saveConfig()
{
    DataSerial.println("-----Save config-----");
    DataSerial.print("ledswitch:");
    DataSerial.print(config.ledswitch);
    DataSerial.print(",r:");
    DataSerial.print(config.r);
    DataSerial.print(",g:");
    DataSerial.print(config.g);
    DataSerial.print(",b:");
    DataSerial.print(config.b);
    DataSerial.print(",w:");
    DataSerial.print(config.w);
    DataSerial.print(",m:");
    DataSerial.println(config.m);
    DataSerial.println("-------------------");

    EEPROM.put(eeAddress, config);
}

/*
   从EEPROM加载参数
*/
void loadConfig()
{
    EEPROM.get(eeAddress, config);
    DataSerial.println("-----Read config-----");
    DataSerial.print("ledswitch:");
    DataSerial.print(config.ledswitch);
    DataSerial.print(",r:");
    DataSerial.print(config.r);
    DataSerial.print(",g:");
    DataSerial.print(config.g);
    DataSerial.print(",b:");
    DataSerial.print(config.b);
    DataSerial.print(",w:");
    DataSerial.print(config.w);
    DataSerial.print(",m:");
    DataSerial.println(config.m);
    DataSerial.println("-------------------");
}

//定时上传状态
void doUploadStatus()
{
    static uint32_t uploadTimeTick = 0;
    static uint8_t stat_cnt = 0;
    static uint8_t ext_stat_cnt = 0;
    if (millis() - uploadTimeTick >= 1000) {
        uploadTimeTick = millis();
        stat_cnt++;
        ext_stat_cnt++;
        if (stat_cnt >= 50) {
            stat_cnt = 0;
            sprintf(strStat,"cmd=stat&status=%d\r\n",config.ledswitch);
            sendUART(strStat);
        }
        if (ext_stat_cnt >= 60) {
            ext_stat_cnt = 0;
            sprintf(strExtStat,"cmd=ext_stat&status=%d|%d|%d|%d|%d\r\n",config.r,config.g,config.b,config.w,config.m);
            sendUART(strExtStat);
        }
    }
}

/*
  检查串口是否有数据
*/
void doUartTick()
{
    if (DataSerial.available() > 0)
    {
        uint8_t t = DataSerial.read();
        buffUart[buffUartIndex++] = t;

        preUartTick = millis();
        if (buffUartIndex >= MAX_PACKETSIZE - 1) {
            buffUartIndex = MAX_PACKETSIZE - 2;
            preUartTick = preUartTick - 100;
        }
    }
    if (buffUartIndex > 0 && (millis() - preUartTick >= 200))
    {    //data ready
        buffUart[buffUartIndex] = 0x00;
        //DataSerial.flush();
        parseUartPackage(buffUart, buffUartIndex);
        buffUartIndex = 0;
    }
}

//处理串口数据
void parseUartPackage(char *p, size_t len)
{
    DataSerial.println("parseUartPackage");
    DataSerial.println(p);
    char * s = NULL, *e = NULL;
    char power[8]; memset(power, 0x00, sizeof(power));
    char r[8]; memset(r, 0x00, sizeof(r));
    char g[8]; memset(g, 0x00, sizeof(g));
    char b[8]; memset(b, 0x00, sizeof(b));
    char w[8]; memset(w, 0x00, sizeof(w));
    char m[8]; memset(m, 0x00, sizeof(m));
    if (strstr(p, "cmd=ctrl") != NULL) {
        s = strstr(p, "message=");
        if (s == NULL) return;
        e = strstr(s, "|");
        if (e == NULL) return;
        memcpy(power, s + strlen("message="), e - s - strlen("message="));
        s = strstr(e + 1, "|");
        if (s == NULL) return;
        memcpy(r, e + 1, s - e - 1);
        e = strstr(s + 1, "|");
        if (e == NULL) return;
        memcpy(g, s + 1, e - s - 1);
        s = strstr(e + 1, "|");
        if (s == NULL) return;
        memcpy(b, e + 1, s - e - 1);
        e = strstr(s + 1, "|");
        if (e == NULL) return;
        memcpy(w, s + 1, e - s - 1);
        s = strstr(e, "\r\n");
        if (s == NULL) return;
        memcpy(m, e + 1, s - e - 1);
        config.ledswitch = atoi(power);
        config.r = atoi(r);
        config.g = atoi(g);
        config.b = atoi(b);
        config.w = atoi(w);
        config.m = atoi(m);
        ctrlLED(config.r,config.g,config.b,config.w,config.m);
        saveConfig();
    }
}

/*
  * 发送数据到串口
 */
void sendUART(char *p, size_t len)
{
    DataSerial.println("[send to UART:]char*");
    DataSerial.println(p);
    DataSerial.write((uint8_t*)p, len);
    delay(50);
}

/*
  * 发送数据到串口
 */
void sendUART(char *p)
{
    DataSerial.println("[send to UART:]string");
    DataSerial.println(p);
    DataSerial.print(p);
    delay(50);
}

//控制LED
void ctrlLED(uint16_t r,uint16_t g,uint16_t b,uint16_t w,uint16_t m)
{
    analogWrite(PWM_R, r);
    analogWrite(PWM_G, g);
    analogWrite(PWM_B, b);
    analogWrite(PWM_W, w);
    analogWrite(PWM_M, m);
}

//初始化LED
void initLED()
{
    pinMode(PWM_R, OUTPUT);
    pinMode(PWM_G, OUTPUT);
    pinMode(PWM_B, OUTPUT);
    pinMode(PWM_W, OUTPUT);
    pinMode(PWM_M, OUTPUT);
    ctrlLED(config.r,config.g,config.b,config.w,config.m);
}

void setup()
{
    //DebugSerial.begin(115200);
    DataSerial.begin(115200);
    loadConfig();
    initLED();
}

void loop()
{
    doUartTick();
    doUploadStatus();
}

注意：

（1）上传arduino程序需先断开DT-06模块的连接，程序上传完成后再插上DT-06模块

arduino UNO控制程序代码：下载地址