Oracle数据库之PL/SQL程序基础设计

http://www.cnblogs.com/hellokitty1/p/4572930.html

DECLARE
/*
 * 声明部分——定义常量、变量、复杂数据类型、游标、用户自定义异常
 */
BEGIN
/*
 * 执行部分——PL/SQL语句和SQL语句
 */
EXCEPTION
/*
 * 异常处理部分——处理运行异常
 */
END;
/*块结束标记 */

要实现PL/SQL程序设计，先介绍如下的基本内容：

二、标识符

PL/SQL程序设计中的标识符定义与SQL的标识符定义的要求相同：

  • 标识符名第一个字符必须为字母
  • 标识符名不分大小写
  • 标识符名不能超过30字符
  • 不能用‘-’(减号)
  • 不能是SQL保留字

注意: 一般不要把变量名声明与表中字段名完全一样，如果这样可能得到不正确的结果。

三、变量

1. 变量定义

声明：

variable_name Type;

示例：

my_var NUMBER(4);

赋值：

variable := expression ;

示例：

my_var := 32 * 8 + 79;
-- 声明并赋值
cnt NUMBER(2) := 3;

2. 变量作用域

在PL/SQL编程中，如果在变量的定义上没有做到统一的话，可能会隐藏一些危险的错误，这样的原因主要是变量的作用域所致。变量的作用域是指变量的有效作用范围，与其它高级语言类似，PL/SQL的变量作用范围特点是：

  • 变量的作用范围是在你所引用的程序单元（块、子程序、包）内。即从声明变量开始到该块的结束。
  • 一个变量（标识）只能在你所引用的块内是可见的。
  • 当一个变量超出了作用范围，PL/SQL引擎就释放用来存放该变量的空间（因为它可能不用了）。
  • 在子块中重新定义该变量后，它的作用仅在该子块内。

四、运算符

1. 关系运算符

运算符 说明
= 等于
<> , != , ~= , ^= 不等于
< 小于
> 大于
<= 小于等于
>= 大于等于

2. 逻辑运算符

运算符 说明
AND 逻辑与
OR 逻辑或
NOT 逻辑非，取反

3. 算术运算符

运算符 说明
+ 加
- 减
* 乘
/ 除

4. 其它运算符

运算符 说明
IS NULL 是空值
BETWEEN AND 介于两者之间
IN 在一列值中间
:= 赋值运算符
=> 关系号
.. 范围运算符
|| 字符连接符

五、数据类型

前面已经介绍过Oracle中的基本数据类型，除了这些基本数据类型外，Oracle中还有其它的数据类型，我们一一来分析。

1. BOOLEAN

该数据用于定义布尔变量，其变量的值为TRUE、FALSE或NULL。注意此类型只能在PL/SQL中使用，表列是没有此类型的。

2. %TYPE

通常用于指定表的某个列的数据类型，可以理解为“的类型”(小技巧：%读“的”)。

示例：

emp_id employee.id%TYPE;

使用%TYPE特性的优点在于：

  • 所引用的数据库列的数据类型可以不必知道。
  • 所引用的数据库列的数据类型可以实时改变，容易保持一致，也不用修改PL/SQL程序。

3. %ROWTYPE

%ROWTYPE操作符，返回一个记录类型，其数据类型和数据库表的数据结构相一致。

示例：

rec employee%ROWTYPE;

使用%ROWTYPE特性的优点在于：

  • 所引用的数据库中列的个数和数据类型可以不必知道。
  • 所引用的数据库中列的个数和数据类型可以实时改变，容易保持一致，也不用修改PL/SQL程序。

4. 复合数据类型

4.1. 记录（Record）

记录类型类似于C语言中的结构数据类型，它把分离的、逻辑相关的、基本数据类型的变量组成一个整体存储起来，它必须包括至少一个标量型或RECORD数据类型的成员，称作PL/SQL RECORD的域(FIELD)，其作用是存放互不相同但逻辑相关的信息。

语法：

TYPE record_name IS RECORD(
    varable1 data_type1  [NOT NULL]  [:= default_value ],
    varable2 data_type2  [NOT NULL]  [:= default_value ],
    ......,
    varablen data_typen  [NOT NULL]  [:= default_value ]
);

在使用记录数据类型变量时，需要先在声明部分先定义记录的组成、记录的变量，然后在执行部分引用该记录变量本身或其中的成员。

示例1：

DECLARE
   -- 定义记录类型
   TYPE TEST_REC IS RECORD(
         rec_name VARCHAR2(30) NOT NULL := ‘匿名‘,
         info VARCHAR2(100)
   );
   -- 声明记录变量
   rec_emp TEST_REC;
BEGIN
   rec_emp.rec_name :=‘刘强东‘;
   rec_emp.info :=‘谈京东的业务发展‘;
   DBMS_OUTPUT.PUT_LINE(rec_emp.rec_name||‘  ‘ ||rec_emp.info);
END;

说明：我们可以使用DBMS_OUTPUT.PUT_LINE(outdata)或DBMS_OUTPUT.PUT(outdata)将处理结果输出到屏幕上。

运行结果：

刘强东  谈京东的业务发展

示例2（示例中所用到的表及数据见文末）：

DECLARE
   --定义与employee表中的几个列相同的记录数据类型
   TYPE RECORD_TYPE_EMPLOYEES IS RECORD(
        e_id employee.id%TYPE,
        e_name employee.name%TYPE,
        e_birth employee.birthday%TYPE,
        e_address employee.address%TYPE,
        e_did employee.did%TYPE
   );
   --声明一个该记录数据类型的记录变量
   emp_record RECORD_TYPE_EMPLOYEES;

BEGIN
   SELECT id, name, birthday, address, did INTO emp_record
   FROM employee
   WHERE id = &emp_id;

   DBMS_OUTPUT.PUT_LINE(‘雇员名称：‘||emp_record.e_name
             ||‘  出生日期：‘||emp_record.e_birth
             ||‘  地址：‘||emp_record.e_address);
END;

说明：可以用SELECT语句对记录变量进行赋值，只要保证记录字段与查询结果列表中的字段相配即可。&emp_id表示接收用户的输入。

紧跟着&符号后面的变量被称为替换变量。替换变量对数据库引擎是“不可见的”。其实PL/SQL会用用户输入的文本内容来替换变量引用。

如果你想在代码的不同地方引用相同的替换变量，那就需要在第一个替换变量前面放两个&符号，这样才会为你保留这个值以便后续使用。

输入2，输出结果：

雇员名称：刘兰  出生日期：03-9月 -85  地址：四川成都

4.2. 表(TABLE)

4.2.1. 索引表

索引表也称为PL/SQL表，它是Oracle早期版本用于处理PL/SQL数组的数据类型。索引表的元素个数没有限制，并且下标可以为负值。

它与记录类型相似，但它是对记录类型的扩展。它可以处理多行记录，使得可以在PL/SQL中模仿数据库中的表。

注意，索引表只能作为PL/SQL复合数据类型使用，而不能作为表列的数据类型使用。

语法结构：

TYPE table_name IS TABLE OF element_type [NOT NULL]
INDEX BY [BINARY_INTEGER | PLS_INTEGER | VARCHAR2];

关键字INDEX BY表示创建一个主键索引，以便引用记录表变量中的特定行。

表是集合类型，集合类型常用方法有：

方法 说明
EXISTS(n) 如果集合的第n个成员存在，则返回true
COUNT 返回已经分配了存储空间即赋值了的成员数量
FIRST 返回成员的最低下标值
LAST 返回成员的最高下标值
PRIOR(n) 返回下标为n的成员的前一个成员的下标。如果没有则返回NULL
NEXT(N) 返回下标为n的成员的后一个成员的下标。如果没有则返回NULL
TRIM TRIM：删除末尾一个成员。
TRIM(n) ：删除末尾n个成员
DELETE DELETE：删除所有成员。
DELETE(n) ：删除第n个成员。DELETE(m, n) ：删除从n到m的成员。
EXTEND EXTEND：添加一个null成员。
EXTEND(n)：添加n个null成员。
EXTEND(n,i)：添加n个成员，其值与第i个成员相同。
LIMIT 返回在varray类型变量中出现的最高下标值

集合方法调用语法为：

collection_name.method_name[(parameters)]

示例1：

DECLARE
    /* 定义索引表类型 */
    TYPE name_index IS TABLE OF employee.name%type INDEX BY binary_integer;
    TYPE charindex is table of employee.name%type index by varchar2(10);
    /* 声明变量 */
    names name_index;
    names2 charindex;
BEGIN
    names(1) := ‘love‘;
    names(2) := ‘lily‘;
    names2(‘girl‘) := ‘Lucy‘;
    names2(‘boy‘) := ‘Tom‘;
    dbms_output.put_line(names(1));
    dbms_output.put_line(names(2));
    dbms_output.put_line(names2(‘girl‘));
    dbms_output.put_line(names2(‘boy‘));
END;

输出结果：

love
lily
Lucy
Tom

示例2：

DECLARE
    /* 定义索引表类型 */
    TYPE name_index IS TABLE OF employee.name%type INDEX BY binary_integer;
    TYPE charindex is table of employee.name%type index by varchar2(10);
    /* 声明变量 */
    names name_index;
    names2 charindex;
BEGIN
    SELECT name INTO names(1) FROM employee WHERE id=3;
    SELECT empname INTO names2(‘name‘) FROM employee WHERE id=5;
    dbms_output.put_line(names(1));
    dbms_output.put_line(names2(‘name‘));
END;

输出结果：

张强
向小梅

示例3：

DECLARE
  TYPE DEPT_TABLE_TYPE IS TABLE OF DEPT%ROWTYPE INDEX BY BINARY_INTEGER;
  dept_table DEPT_TABLE_TYPE;
  cnt number(2) :=4;
BEGIN
  FOR i IN 1 .. cnt LOOP
    SELECT * INTO dept_table(i) FROM DEPT WHERE id=i;
  END LOOP;
  FOR i IN 1 .. cnt LOOP
  DBMS_OUTPUT.PUT_LINE(‘Department id: ‘||dept_table(i).id);
  DBMS_OUTPUT.PUT_LINE(‘Department name: ‘|| dept_table(i).name);
  END LOOP;
END;

输出结果：

Department id: 1
Department name: 财务部
Department id: 2
Department name: 市场部
Department id: 3
Department name: 综合部
Department id: 4
Department name: 研发部

4.2.2 嵌套表

嵌套表的元素下标从1开始，并且元素个数没有限制。嵌套表数组元素值可以是稀疏的。

注意：索引表类型不能作为表列的数据类型使用，但嵌套表类型可以作为表列的数据类型。

语法结构：

TYPE type_name IS TABLE OF element_type;

示例1：

DECLARE
    TYPE EMP_TABLE_TYPE IS TABLE OF employee.name%TYPE;
    emp_table EMP_TABLE_TYPE;
BEGIN
    emp_table := EMP_TABLE_TYPE(‘ ‘,‘ ‘,‘ ‘);--这里必须使用构造方法初始化嵌套表变量。
    SELECT name INTO emp_table(2) FROM employee
    WHERE id=&emp_id;
    DBMS_OUTPUT.PUT_LINE(‘姓名：‘||emp_table(2));
END;

输入2，输出结果：

姓名：刘兰

在表列中也可以使用嵌套表。

在表列中使用嵌套表类型，必须首先使用CREATE TYPE命令建立嵌套表类型。另外注意，必须要为嵌套表列指定专门的存储表。

示例2：

CREATE TYPE phone_type IS TABLE OF varchar2(20);

CREATE TABLE employee(
    id number(4),
    name varchar2(10),
    sal number(6,2),
    phone phone_type
)nested table phone store as phone_table;

-- 在嵌套表中插入数据
BEGIN
    INSERT INTO employee VALUES(1, ‘TOM‘, 800, phone_type(‘028-90909800‘, ‘13913001300‘));
END;

-- 在嵌套表中检索数据
DECLARE
    phone_table phone_type;
BEGIN
    SELECT phone INTO phone_table FROM employee WHERE id=1;
    FOR i IN 1..phone_table.COUNT LOOP
        dbms_output.put_line(‘电话号码：‘||phone_table(i));
    END LOOP;
END;

-- 在嵌套表中更新数据
DECLARE
    phone_table phone_type:=phone_type(‘028-10001000‘, ‘139800900100‘);
BEGIN
    UPDATE employee SET phone=phone_table WHERE id=1;
END;

4.3. 数组（VARRAY）

数组是具有相同数据类型的一组成员的集合。每个成员都有一个唯一的下标，它取决于成员在数组中的位置。

语法结构：

TYPE varray_name IS VARRAY(size) OF element_type [NOT NULL];

示例：

DECLARE
   --定义一个最多保存5个VARCHAR(25)数据类型成员的VARRAY数据类型
   TYPE ARRAY_TYPE IS VARRAY(5) OF VARCHAR(25);
   --声明一个该VARRAY数据类型的变量
   my_array ARRAY_TYPE;

BEGIN
   --用构造函数语法赋予初值
   my_array := ARRAY_TYPE
         (‘中国‘, ‘美国‘, ‘英国‘, ‘日本‘, NULL);

   DBMS_OUTPUT.PUT_LINE(‘地区名称：‘||my_array(1)||‘、‘
                                    ||my_array(2)||‘、‘
                                    ||my_array(3)||‘、‘
                                    ||my_array(4));
   DBMS_OUTPUT.PUT_LINE(‘赋予初值NULL的第5个成员的值：‘||my_array(5));
   --也可以这样对成员赋值
   my_array(5) := ‘法国‘;
   DBMS_OUTPUT.PUT_LINE(‘第5个成员的值：‘||my_array(5));
END;

输出结果：

地区名称：中国、美国、英国、日本
赋予初值NULL的第5个成员的值：
第5个成员的值：法国

5. 绑定变量

绑定变量是在主机环境中定义的变量。在PL/SQL 程序中可以使用绑定变量作为他们将要使用的其它变量。为了在PL/SQL 环境中声明绑定变量，使用命令VAR或VARIABLE。

当在SQL*Plus中与PL/SQL块之间进行数据交互时，需要使用SQL*Plus绑定变量来完成。

当在PL/SQL中引用非PL/SQL变量时，必须要在非PL/SQL变量前加冒号(“:”)。

示例：

VARIABLE name varchar2(10);
/
BEGIN
    SELECT name INTO :name FROM employee
    WHERE id = 1;
end;
/
print name;

输出结果：

name
---------
李飞

六、常用类型转换函数

CHAR 转换为 NUMBER：

使用 TO_NUMBER 函数来完成字符到数字的转换，如：

v_total := TO_NUMBER(‘100.0‘) + 25.5;

NUMBER 转换为CHAR：

使用 TO_CHAR 函数可以实现数字到字符的转换，如：

v_comm := TO_CHAR(‘12.34‘) || ‘元‘ ;

字符转换为日期：

使用 TO_DATE 函数可以实现 字符到日期的转换，如：

v_date := TO_DATE(‘2015.06.11‘,‘yyyy.mm.dd‘);

日期转换为字符：

使用 TO_CHAR 函数可以实现日期到字符的转换，如：

v_to_day := TO_CHAR(SYSDATE, ‘yyyy.mm.dd hh24:mi:ss‘) ;

七、RETURNNING的使用

示例1：

DECLARE
   row_id ROWID;
   info    VARCHAR2(40);
BEGIN
  INSERT INTO dept VALUES (10, ‘外交部‘)
  RETURNING rowid, name||‘:‘||to_char(id) INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE(‘ROWID:‘||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

说明：

数据类型ROWID用于存放数据的行号。

RETURNING子句作用：用于检索INSERT语句中所影响的数据行数，当INSERT语句使用VALUES子句插入数据时，RETURNING 字句还可将列表达式、ROWID和REF值返回到输出变量中。使用RETURNING子句是应注意以下几点限制：

  • 不能与DML语句和远程对象一起使用；
  • 不能检索LONG类型信息；
  • 当通过视图向基表中插入数据时，只能与单基表视图一起使用。

示例2：

DECLARE
   row_id ROWID;
   info   VARCHAR2(40);
BEGIN
  UPDATE dept SET id=20 WHERE name=‘外交部‘
  RETURNING rowid, name||‘:‘||to_char(id) INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE(‘ROWID:‘||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

说明：

RETURNING子句用于检索被修改行的信息。当UPDATE语句修改单行数据时，RETURNING子句可以检索被修改行的ROWID和REF值，以及行中被修改列的列表达式，并可将他们存储到PL/SQL变量或复合变量中；当UPDATE语句修改多行数据时，RETURNING子句可以将被修改行的ROWID和REF值，以及列表达式值返回到复合变量数组中。在UPDATE中使用RETURNING 子句的限制与INSERT语句中对RETURNING子句的限制相同。

示例3：

DECLARE
   row_id ROWID;
   info   VARCHAR2(40);
BEGIN
  DELETE dept WHERE id=20
  RETURNING rowid, name||‘:‘||to_char(id) INTO row_id, info;
  DBMS_OUTPUT.PUT_LINE(‘ROWID:‘||row_id);
  DBMS_OUTPUT.PUT_LINE(info);
END;

说明：

RETURNING子句用于检索被删除行的信息：当DELETE语句删除单行数据时，RETURNING子句可以检索被删除行的ROWID和REF值，以及被删除列的列表达式，并可将他们存储到PL/SQL变量或复合变量中；当DELETE语句删除多行数据时，RETURNING子句可以将被删除行的ROWID和REF值，以及列表达式值返回到复合变量数组中。在DELETE中使用RETURNING子句的限制与INSERT语句中对RETURNING子句的限制相同。

八、注释

在PL/SQL里，有两种注释：

  • 使用’–-’(双减号)注释，它的作用范围是只能在一行有效。
  • 使用’/* */’注释，这是多行注释，可注释一行，也可注释多行。

示例：

DECLARE
  --定义v_sal变量
  v_sal NUMBER(6，2);
BEGIN
  /*
   给变量赋值，
   然后打印此变量
  */
  v_sal := 1000;
  dbms_output.put_line(v_sal);
END;

各示例中所涉及的表及测试数据

-- 创建表
create table DEPT -- 部门
(
  id   NUMBER(4) not null constraint PK_DEPT_ID primary key,
  name VARCHAR2(20)
);

create table EMPLOYEE -- 员工
(
  id       NUMBER(4) not null constraint PK_EMP_ID primary key,
  name     VARCHAR2(20) not null,
  birthday DATE,
  address  VARCHAR2(100),
  did      NUMBER(4),
  constraint FK_EMP_DEPT foreign key (DID) references DEPT (ID)
);

-- 添加测试数据
INSERT INTO DEPT VALUES(1, ‘财务部‘);
INSERT INTO DEPT VALUES(2, ‘市场部‘);
INSERT INTO DEPT VALUES(3, ‘综合部‘);
INSERT INTO DEPT VALUES(4, ‘研发部‘);
INSERT INTO DEPT VALUES(5, ‘网络部‘);

INSERT INTO EMPLOYEE VALUES(1, ‘李飞‘, TO_DATE(‘1975.07.03‘,‘yyyy.mm.dd‘), ‘四川成都‘, 1);
INSERT INTO EMPLOYEE VALUES(2, ‘刘兰‘, TO_DATE(‘1985.09.03‘,‘yyyy.mm.dd‘), ‘四川成都‘, 1);
INSERT INTO EMPLOYEE VALUES(3, ‘张强‘, TO_DATE(‘1987.11.22‘,‘yyyy.mm.dd‘), ‘广东广州‘, 2);
INSERT INTO EMPLOYEE VALUES(4, ‘刘武龙‘, TO_DATE(‘1979.07.18‘,‘yyyy.mm.dd‘), ‘陕西西安‘, 2);
INSERT INTO EMPLOYEE VALUES(5, ‘向小梅‘, TO_DATE(‘1982.03.03‘,‘yyyy.mm.dd‘), ‘四川成都‘, 2);
INSERT INTO EMPLOYEE VALUES(6, ‘周斌‘, TO_DATE(‘1985.11.08‘,‘yyyy.mm.dd‘), ‘四川成都‘, 4);
INSERT INTO EMPLOYEE VALUES(7, ‘王强‘, TO_DATE(‘1985.01.25‘,‘yyyy.mm.dd‘), ‘四川成都‘, 4);
时间： 2024-08-10 19:07:20

Oracle数据库之PL/SQL程序基础设计的相关文章

PL/SQL程序基础设计

一.PL/SQL块结构 前边我们已经介绍了PL/SQL块的结构,再来回顾一下: DECLARE /* * 声明部分——定义常量.变量.复杂数据类型.游标.用户自定义异常 */ BEGIN /* * 执行部分——PL/SQL语句和SQL语句 */ EXCEPTION /* * 异常处理部分——处理运行异常 */ END; /*块结束标记 */ 要实现PL/SQL程序设计,先介绍如下的基本内容: 二.标识符 PL/SQL程序设计中的标识符定义与SQL的标识符定义的要求相同: 标识符名第一个字符必须为

Oracle数据库之PL/SQL程序设计基础

PL/SQL程序设计基础 一.PL/SQL块结构 前边我们已经介绍了PL/SQL块的结构,再来回顾一下: DECLARE /* * 声明部分——定义常量.变量.复杂数据类型.游标.用户自定义异常 */ BEGIN /* * 执行部分——PL/SQL语句和SQL语句 */ EXCEPTION /* * 异常处理部分——处理运行异常 */ END; /*块结束标记 */ 要实现PL/SQL程序设计,先介绍如下的基本内容: 二.标识符 PL/SQL程序设计中的标识符定义与SQL的标识符定义的要求相同:

Oracle数据库之PL/SQL过程与函数

Oracle数据库之PL/SQL过程与函数 PL/SQL块分为匿名块与命名块,命名块又包含子程序.包和触发器. 过程和函数统称为PL/SQL子程序,我们可以将商业逻辑.企业规则写成过程或函数保存到数据库中,以便共享. 过程和函数均存储在数据库中,并通过参数与其调用者交换信息.过程和函数的唯一区别是函数总向调用者返回数据,而过程不返回数据. 1. 存储过程概念 存储过程(Stored Procedure)是在大型数据库系统中,一组为了完成特定功能的SQL语句集,存储在数据库中.经过第一次编译后再次

Oracle数据库之PL/SQL异常处理

Oracle数据库之PL/SQL异常处理 异常指的是在程序运行过程中发生的异常事件,通常是由硬件问题或者程序设计问题所导致的. PL/SQL程序设计过程中,即使是写得最好的程序也可能会遇到错误或未预料到的事件.一个健壮的程序都应该能够正确处理各种异常情况,并尽可能从中恢复. 1. 异常处理 异常处理是用来处理正常执行过程中未预料的事件.PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行. PL/SQL编程过程中,有三种类型的异常: 1.预定义异常 对这种异常情况的处

Oracle数据库之PL/SQL程序设计简介

有利于客户/服务器环境应用的运行 对于客户/服务器环境来说,真正的瓶颈是网络上.无论网络多快,只要客户端与服务器进行大量的数据交换,应用运行的效率自然就回受到影响.如果使用PL/SQL进行编程,将这种具有大量数据处理的应用放在服务器执行,自然就省去了数据在网上的传输时间. 适合于客户环境 PL/SQL由于分为数据库PL/SQL部分和工具PL/SQL.对于客户端来说,PL/SQL可以嵌套到相应的工具中,客户端程序可以执行本地包含PL/SQL部分,也可以向服务发SQL命令或激活服务器端的PL/SQL

Oracle数据库之PL/SQL游标

1. 游标概念 字面意思是游动的光标,是指向上下文区域的句柄或指针. 在PL/SQL块中执行CRUD操作时,ORACLE会在内存中为其分配上下文区.用数据库语言来描述游标就是:映射在上下文区结果集中一行数据上的位置实体. 用户可以使用游标访问结果集中的任意一行数据,将游标指向某行后,即可对该行数据进行操作.游标为应用提供了一种对具有多行数据查询结果集中的每一行数据分别进行单独处理的方法,是设计嵌入式SQL语句的应用程序的常用编程方式. 在每个用户会话中,可以同时打开多个游标,其最大数量由数据库初

Oracle数据库之PL/SQL触发器

1. 介绍 触发器(trigger)是数据库提供给程序员和数据分析员来保证数据完整性的一种方法,它是与表事件相关的特殊的存储过程,它的执行不是由程序调用,也不是手工启动,而是由事件来触发,比如当对一个表进行操作(insert,delete,update)时就会激活它执行.触发器经常用于加强数据的完整性约束和业务规则等. ORACLE触发器有三种类型,分别是:DML触发器.替代触发器和系统触发器. DML触发器 顾名思义,DML触发器是由DML语句触发的.例如数据库的INSERT.UPDATE.D

ORACLE数据库之PL/SQL触发器、rownum、动态SQL、数据库之视图与索引

WHEN子句说明触发约束条件.Condition为一个逻辑表达时,其中必须包含相关名称,而不能包含查询语句,也不能调用PL/SQL函数.WHEN子句指定的触发约束条件只能用在BEFORE和AFTER行触发器中,不能用在INSTEAD OF行触发器和其它类型的触发器中. -- 创建记录操作事件的表 CREATE TABLE event_table( event VARCHAR2(50), time DATE ); -- 创建触发器 CREATE OR REPLACE TRIGGER tr_star

oracle数据库使用PL/sql导入excel数据

1.打开PL/SQL工具,菜单进入   工具>ODBC导入器(菜单列表倒数第二): 2.连接数据库与选择导入的excel文件表: 3.选择导入的表以及excel与数据库表字段之间的对应关系: 原文地址:https://www.cnblogs.com/whitemouseV2-0/p/10837714.html