ｇｄｂ的user-define command

搜索：　user-defined例子。

# save this file in ~/.gdb or some where easy to find.
# then in ~/.gdbinit add the following line...
# source ~/.gdb/osip_gdb_util
#
# help p_osip_list_size
# help p_osip_list

define p_osip_list_size
        set $list = ($arg0)
        set $list_size = 0
        set $node = $list->node
        while ($node != 0)
                set $list_size++
                set $node = (__node_t *)$node->next
        end

        printf "List size: %d", $list_size
end
document p_osip_list_size
p_osip_list_size <list>: Print size of osip list
end

define p_osip_list
        set $list = ($arg0)
        set $list_size = 0
        set $node = $list->node
        while ($node != 0)
                set $list_size++
                print $node->element
                set $node = (__node_t *)$node->next
        end
end
document p_osip_list
p_osip_list <list>: Prints the content of the list.
To see the value, cast the information back to the original form.
For example: *(osip_generic_param_t)$1
end