自动加域脚本

因为经常需要给公司员工电脑加域，以及其他的一些设置。一直想着做一个自动加域的批处理。

参照网上查到的各种信息，终于做成了一个适合自己的脚本。

分三个批处理win7需要以下文件1.bat ,joindomain.bat,clean.bat,  需要的程序netdom.exe netdom.exe.mui(可以在server2008系统中提取,32位和64位程序不同)

1.bat 负责修改机器名称

joindomain.bat 负责加入网域，将用户域账号加入本地组

clean.bat 负责清理脚本，添加权限，更新策略

--------------------------------------------------------------------------------------------------------------------------------------

1.bat

@ECHO off

color 4E

mode con: cols=75 lines=35

title    ⅸ  Auto Join Domain @neal ⅷ

ECHO

ECHO                               自动加域批处理

ECHO

ECHO

ECHO 启动相关系统服务中..........

sc config LmHosts start= AUTO

net start "TCP/IP NetBIOS Helper"

sc config Browser start= AUTO

net start "Computer Browser"

sc config Winmgmt start= AUTO

net start "Windows Management Instrumentation"

sc config LanmanServer start= AUTO

net start "Server"

sc config LanmanWorkstation start= AUTO

net start "Workstation"

ECHO.

ECHO 服务启动完成......

pause>nul

cls

ECHO.

ECHO

ECHO                               修改机器名称

ECHO

ECHO

ECHO.

ECHO 机器名类似此格式(ipt-000000-zida)

ECHO.

ECHO

ECHO.

set /p name=请输入机器名称：

reg add "HKEY_LOCAL_MACHINE\System\ControlSet001\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet001\Control\ComputerName\ComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet001\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet002\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet002\Control\ComputerName\ComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet002\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\ControlSet002\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ComputerName" /v ComputerName /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f >nul 2>nul

ECHO.

ECHO 机器名修改完毕......

pause>nul

cls

ECHO.

ECHO

ECHO                        设置重启后的程序

ECHO

ECHO

ECHO.

::copy相应的文档至本机

copy netdom.exe C:\Windows\System32 /y

copy joindomain.bat C:\Windows\System32 /y

copy netdom.exe.mui C:\Windows\System32\en-US /y

copy clean.bat c:\windows\System32 /y

::设置重启后运行joindomain.bat

REG ADD "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v joindomain /t reg_sz /d "C:\Windows\System32\joindomain.bat" /f >nul

::修改本机自动登录，省去重启后再输入密码

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultUserName /t REG_SZ /d administrator /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultDomainName /t REG_SZ /d %name% /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultPassword /t REG_SZ /d 本机管理员密码 /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v AutoAdminLogon /t REG_SZ /d 1 /f

ECHO.

ECHO 设置完毕将重启系统......

pause>nul

shutdown.exe -r -t 0

--------------------------------------------------------------------------------------------------------------------------------------

joindomain.bat

@ECHO off

color 4E

mode con: cols=75 lines=35

title    ⅸ  Auto Join Domain @neal ⅷ

ECHO.

ECHO

ECHO                           选择ou加入网域

ECHO

ECHO.

ECHO

ECHO.

ECHO  1. computers

ECHO.

ECHO  2. abc

ECHO.

ECHO  3. def

ECHO.

ECHO

ECHO.

set OU=

set/p OU=请输入需要加入的ou:

if %OU% EQU 1 (set OUName=computers)

if %OU% EQU 2 (set OUName=abc)

if %OU% EQU 3 (set OUName=def)

netdom join %computername% /Domain:abc.com /ou:ou=%OUName%,ou="Workstations",dc=abc,dc=com /Userd:abc\域管理员账号 /Passwordd:域管理员密码

pause

cls

:start

ECHO.

ECHO

ECHO                          将用户域账号加入本机群组

ECHO

ECHO.

ECHO

echo.

echo a. administrator

echo.

echo p. powerusers

echo.

set /p numis=请选择(a\p):

if /i "%numis%"=="a" goto a

if /i "%numis%"=="p" (goto p) else (echo 选择错误&&pause>nul&&goto start)

:a

echo 加入administrators组

set username=

set/p username=输入用户的域账号（abc\xxx）

net localgroup "administrators" ies\%username% /add

ECHO.

ECHO 加入成功......

goto r

:p

echo 加入powerusers组

set username=

set/p username=输入用户的域账号（abc\xxx）

net localgroup "power users" ies\%username% /add

ECHO.

ECHO 加入成功......

goto r

:r

pause>nul

cls

ECHO.

ECHO

ECHO                               重启前的设置

ECHO

ECHO

ECHO.

::设置重启后运行的脚本

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v clean /t reg_sz /d "C:\Windows\System32\clean.bat" /f >nul

::因为加域后DefaultDomainName会有改变，重新设置下自动登录

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultUserName /t REG_SZ /d administrator /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultDomainName /t REG_SZ /d %computername% /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultPassword /t REG_SZ /d 本机管理员密码 /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v AutoAdminLogon /t REG_SZ /d 1 /f

ECHO.

ECHO 将自动重启

pause>nul

shutdown.exe -r -t 0

---------------------------------------------------------------------------------------------------------------------------------------

clean.bat

@ECHO off

color 4E

mode con: cols=75 lines=35

title    ⅸ  Auto clean @neal ⅷ

::安全问题，自动清除脚本

del C:\Windows\System32\joindomain.bat

del C:\Windows\System32\netdom.exe

del C:\Windows\System32\en-US\netdom.exe.mui

rd /s /q "C:\Users\Administrator\Desktop\autojoinwin732"

::给d,e,f盘添加pouser user的完全控制权限

ECHO 添加DEF盘pouser user的完全控制权限

cacls d:\ /g "power users":f /e

cacls e:\ /g "power users":f /e

cacls f:\ /g "power users":f /e

::取消自动登录，及修改其中注册表中保存的管理员密码

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v AutoAdminLogon /t REG_SZ /d 0 /f

REG ADD "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultPassword /t REG_SZ /d IES=123 /f

ECHO 更新组策略

gpupdate /force

ECHO 任意键重启......

pause>nul

shutdown.exe -r -t 0

时间： 2024-10-12 22:07:05

自动加域脚本的相关文章

自动加域脚本，bat和vbs配合使用，使加域操作更简单

我的实验:编写自动加域脚本(总结)1.自动加域脚本的目的.A.减少重复繁杂的必要操作,提高工作效率.B.使加域操作更简单,更有乐趣. 2.自动加域的实现方式,分为三个步骤.A.使用bat和vbs相互配合.(因为本人编程水平不高)B.更改电脑名字.(不需要重启电脑)C.更改电脑IP地址及DSN.(选择自动获取还使手动配置)D.调用Vbs文件完成自动加域操作.(不解释为什么要调用vbs,而不直接用bat完成) 3.相关文件.A.链接:https://pan.baidu.com/s/1sZmCisS1

【AD】WinXP Win7x64 自动加域脚本

http://bbs.51cto.com/thread-968398-1.html 受到链接中专家的启发,以及网上的一些资料. 自己写了一个win7x64 winxp加域退域脚本.测试DC是Server2008R2. 使用方法. 以win7x64为例 将AD文件夹整个放到C盘根目录下. 内部文件 将目标BAT内的Domain,DNS和帐号密码都换成你自己的. 然后右击其中的加域,运行. 界面大致如图 根据提示一步一步操作. 退域也类似. 这个和链接中的区别是不需要先更改名再重启再加域,而是可以先

【AD】WinXP Win7x86/x64 自动加域脚本 更新20151109

注:运行修改计算机的账号必须具有管理员权限 -reboot参数我设置的5,可能会看不到echo y传递的结果,你可以设置成10. http://bbs.51cto.com/thread-968398-1.html 受到链接中专家的启发,以及网上的一些资料. 二次更新20151108这次更新主要内容是不需要放在C盘,你可以放在任何一个地方,也可以放在共享目录.并且不需要再去某个目录下选择对应操作系统的脚本,脚本会自动判断当前系统,也能判断win7是32位还是64位.附件中带了一个脚本批量替换工具,

自动加域--Script

自动加域--Script说到自动加域,我们作为一个运维管理员来说,是必须要掌握了的 ,通过脚本提高管理员的工作效率,一般可以将自动加域脚本(前提是需要将脚本加密,内部有明文账户及密码)通过共享的方式然后用户手动执行,前一段时间领导也有这个需求,所以就总了一些,分享给有需要的.一般分为两步,首先是计算更改计算机名,其次就是加域了:最后是需要将用户增加到管理员组中,保证用户有足够的权限进行操作.首先是修改计算机名:执行会提示当前的计算机名,然后输入新的计算机名,单击确认即可: Dim reval S

使用autoit实现自动加域

#Region ;**** 由 AccAu3Wrapper_GUI 创建指令 **** #AutoIt3Wrapper_Icon=C:\Users\helpdesk07\Desktop\autoit脚本\fuwuqi.ico #AutoIt3Wrapper_OutFile_x64=成品脚本\jiayuv2.exe #AutoIt3Wrapper_Res_Comment=不重起自动修改计算机名,加网域 #AutoIt3Wrapper_Res_LegalCopyright=孙超 #AutoIt3Wr

Windows10一键加域退域PS脚本

批处理@echo offclsecho .echo .echo 先修改ps脚本中的账号密码echo. 1.加域echo. 2.退域set /p a= 输入数字:if %a%==1 goto 加域if %a%==2 goto 退域 :加域powershell.exe set-executionpolicy remotesigned -forcepowershell.exe %~dp0batchfile\join-domain-for-win10.ps1pauseexit :退域powershell

shell脚本自动加黑恶意攻击IP

shell脚本自动加黑恶意攻击IP 系统环境:Centos 6.5 X64 如果我们对所有用户开放了SSH 22端口,那么我们就可以在/var/log/secure文件里查看,这里面全是恶意攻击的IP ,那么我们又该如何拒绝这些IP在下次攻击时直接把他拉黑,封掉呢? 或者这个IP再试图登陆4次或7次我就把他拒绝了,把他这个IP永久的封掉呢?这个时候我们就可以用这下面这个脚本来实现. [[email protected] ssh]# vi /etc/ssh/blocksship #!/bin/ba

跨域加载脚本或页面获取内容

$.extend({     /**     * 跨域装载JS脚本,获取页面窗口对象,从而获得DOM内容     * @param string url 需要读取的脚本地址     * @param function callback 回调函数,参数为载入后的窗口win对象     * @param string charset 指定字符编码     */     'crossGetScript':function(url,callback,charset){                  

自动备份加域工具

大家装系统都装过很多了,公司电脑故障重装系统后都要改电脑名加域,配置磁盘权限.设置邮箱等,在重装系统请都要抄电脑名,ip地址,邮箱用户. 在系统进不去的时候,这些信息只有从其他地方获取了,都是些重复工作.基于这些,为了维护更加方便,近来我花时间开发了一个装机自动备份恢复工具,暂且叫做Jtools 吧 软件使用python语言开发,软件实现以下一些功能: *备份用户状态 *备份电脑名与IP地址 *自动恢复电脑名与加人域并设置域用户权限 *自动恢复用户状态配置 都是些实用功能,暂且只支持XP ,待有